`clojure.string/split`¶

Type: function Added: Clojure 1.2 Examples: 8 Runnable: 4

([s re] [s re limit])

Splits string on a regular expression. Optional argument limit is the maximum number of parts. Not lazy. Returns vector of the parts. Trailing empty strings are not returned - pass limit of -1 to return all.

Examples¶

by nipra on 2010-07-17 . May have evaluation errors.

(require '[clojure.string :as str])

(str/split "Clojure is awesome!" #" ")
["Clojure" "is" "awesome!"]

(str/split "q1w2e3r4t5y6u7i8o9p0" #"\d+")
["q" "w" "e" "r" "t" "y" "u" "i" "o" "p"]

;; Note that the 'limit' arg is the maximum number of strings to
;; return (not the number of splits)
(str/split "q1w2e3r4t5y6u7i8o9p0" #"\d+" 5)
["q" "w" "e" "r" "t5y6u7i8o9p0"]

;; to get back all the characters of a string, as a vector of strings:
(str/split " q1w2 " #"")
[" " "q" "1" "w" "2" " "]
;; Note: sequence, in contrast, would return characters.

;; Using lookarounds (lookahead, lookbehind) one can keep the matching characters (aka delimiters or splitters):
(str/split " something and ACamelName " #"(?=[A-Z])")
[" something and " "A" "Camel" "Name "]

;; If the pattern is not found, we get back the original string untouched:
(str/split "a" #"b")
["a"]

(str/split " " #"b")
[" "]

(str/split "" #"b")
[""]

;; If everything matches, an empty vector is returned!
(str/split "a" #"a")
[]

(str/split "aaa" #"a")
[]

;; but:
(str/split "" #"")
[""]

by Santosh on 2010-10-03 . May have evaluation errors.

by jafingerhut on 2011-12-15 . May have evaluation errors.

(use '[clojure.string :only (split triml)])

;; Splitting on whitespace is a common desire.
(split "Some words to split" #"\s+")
["Some" "words" "to" "split"]

;; By using the pattern #"\s+", we split on all occurrences of one or
;; more consecutive whitespace characters.
(split "Some    words   with\tother whitespace      \n" #"\s+")
["Some" "words" "with" "other" "whitespace"]

;; If you are used to Perl's special behavior of split(' ', $str),
;; where it ignores leading whitespace in the string to be split, this
;; does not quite do it.
(split "   Leading whitespace causes empty first string" #"\s+")
["" "Leading" "whitespace" "causes" "empty" "first" "string"]

;; This will do it.
(defn perl-split-on-space [s]
         (split (triml s) #"\s+"))
#'user/perl-split-on-space
(perl-split-on-space "   This is often what you want   ")
["This" "is" "often" "what" "you" "want"]

;; There might be cases where you want this instead.
(split "Some    words   with\tother whitespace      \n" #"\s")
["Some" "" "" "" "words" "" "" "with" "other" "whitespace"]

by jafingerhut on 2011-12-15

(use '[clojure.string :only (split)])

;; Split on every occurrence of : character
(split "root:*:0:0:admin:/var/root:/bin/sh" #":")
["root" "*" "0" "0" "admin" "/var/root" "/bin/sh"]

;; Empty strings are returned when two colons appear consecutively in
;; the string to be split.
(split "root::0:0::/var/root:/bin/sh" #":")
["root" "" "0" "0" "" "/var/root" "/bin/sh"]

;; Without specifying a limit, any empty strings at the end are
;; omitted.
(split "root::0:0:admin:/var/root:" #":")
["root" "" "0" "0" "admin" "/var/root"]
(split "root::0:0:admin::" #":")
["root" "" "0" "0" "admin"]

;; If you want all of the fields, even trailing empty ones, use a
;; negative limit.
(split "root::0:0:admin:/var/root:" #":" -1)
["root" "" "0" "0" "admin" "/var/root" ""]
(split "root::0:0:admin::" #":" -1)
["root" "" "0" "0" "admin" "" ""]

;; Use a positive limit of n to limit the maximum number of strings in
;; the return value to n.  If it returns exactly n strings, the last
;; contains everything left over after splitting off the n-1 earlier
;; strings.
(split "root::0:0:admin:/var/root:" #":" 2)
["root" ":0:0:admin:/var/root:"]
(split "root::0:0:admin:/var/root:" #":" 3)
["root" "" "0:0:admin:/var/root:"]
(split "root::0:0:admin:/var/root:" #":" 4)
["root" "" "0" "0:admin:/var/root:"]
(split "root::0:0:admin:/var/root:" #":" 15)
["root" "" "0" "0" "admin" "/var/root" ""]

by octopusgrabbus on 2013-01-20 . May have evaluation errors.

by jafingerhut on 2013-09-13

by cljlc on 2018-02-21

by themustafabasit on 2020-09-25

Note by Jacolyte¶

user=> (clojure.string/split "foo bar") java.lang.ClassNotFoundException: clojure.string

Do I need to require / use anything?

Note by rustem.suniev¶

You need to add a namespace: user => (use 'clojure.string)

Note by cocoOS¶

I 've a doubt...in ruby if I've this:

bignumber="2938434"

I can do this

bignumber.split("")

and get ("2", "9", "3", "8" .....)

How can I do this with clojure?...thanks

Note by Domon¶

Hi, cocoOS. You may want to do it like this:

user=> (use '[clojure.string :only (split)])
nil
user=> (def bignumber "2938434")
#'user/bignumber
user=> (split bignumber #"")
["" "2" "9" "3" "8" "4" "3" "4"]

You will have to filter out the empty string.

But there are other ways, like:

user=> (map str (vec bignumber))
("2" "9" "3" "8" "4" "3" "4")

Note by Iceland_jack¶

user=> (seq "2938434")
(\2 \9 \3 \8 \4 \3 \4)

might also be what you want.

Note by Instinct212¶

Thanks for the help Domon and Iceland_jack, one more question:

Say I have used sequence in the way:

user=> (seq "2938434") (\2 \9 \3 \8 \4 \3 \4)

If I only wanted to access the 4^th item in the sequence (which is 8), how would I do so? Aside from using (next (next (next ...))) ? Just trying to index it giving that I want position 4

Note by olivergeorge¶

When limit=1 the original string is returned

(clojure.string/split "abcd" #"a" 1)
=> ["abcd"]

(clojure.string/split "abcd" #"a" 2)
=> ["" "bcd"]

Note by Yuhta¶

@Instinct212

(nth (seq "2938434") 3)
=> \8

Note by rux¶

There is a change in behaviour between Java 7 and Java 8 that can affect the returned values. "When there is a positive-width match at the beginning of this string then an empty leading substring is included at the beginning of the resulting array. A zero-width match at the beginning however never produces such empty leading substring." was added to the docs for split().

Both run with Clojure 1.8, the code below splits a string based on capital letters, but...

in Java 7

(clojure.string/split "PrimaryEmailAddr" #"(?=[A-Z])")
=> ["" "Primary" "Email" "Addr"]

⁠⁠⁠in Java 8

(clojure.string/split "PrimaryEmailAddr" #"(?=[A-Z])")
=> ["Primary" "Email" "Addr"]

clojure.string/split¶