`clojure.core/reader-conditional?`¶

Type: function Added: Clojure 1.7 Examples: 2 Runnable: 0

([value])

Return true if the value is the data representation of a reader conditional

Examples¶

by svenschoenung on 2017-05-28 . May have evaluation errors.

;;;; Let's say we have the source code for a Clojure program:

(def source-code
  "(defn str-to [type s]
     (case type
       :int #?(:clj (Integer/parseInt s) :cljs (js/parseInt s))
       #?@(:clj [:long (Long/parseLong s)])
       :float #?(:clj (Float/parseFloat s) :cljs (js/parseFloat s))
       #?@(:clj [:double (Double/parseDouble s)])))")

;;;; Here's a function that finds all the reader conditionals
;;;; in a given source code which contain a specific platform tag:

(defn find-reader-conditionals [code tag]
  (->> code
    (read-string {:read-cond :preserve}) ;; read into Clojure data structures
    (tree-seq seqable? identity)         ;; lazy seq of all forms
    (filter reader-conditional?)         ;; keep only reader conditionals
    (filter #(some #{tag} (:form %)))))  ;; keep only reader conds with tag

(pprint (find-reader-conditionals source-code :clj))
;;=> (#?(:clj (Integer/parseInt s) :cljs (js/parseInt s))
;;    #?@(:clj [:long (Long/parseLong s)])
;;    #?(:clj (Float/parseFloat s) :cljs (js/parseFloat s))
;;    #?@(:clj [:double (Double/parseDouble s)]))

(pprint (find-reader-conditionals source-code :cljs))
;;=> (#?(:clj (Integer/parseInt s) :cljs (js/parseInt s))
;;    #?(:clj (Float/parseFloat s) :cljs (js/parseFloat s)))

clojure.core/reader-conditional?¶

Examples¶

See also¶

`clojure.core/reader-conditional?`¶