clojure.core/juxt

View this page on ClojureDocs

Type: function Added: Clojure 1.1 Examples: 12 Runnable: 7

([f] [f g] [f g h] [f g h & fs])

Takes a set of functions and returns a fn that is the juxtaposition of those fns. The returned fn takes a variable number of args, and returns a vector containing the result of applying each fn to the args (left-to-right). ((juxt a b c) x) => [(a x) (b x) (c x)]

Examples

by kotarak on 2010-07-15 ▶

;; Extract values from a map, treating keywords as functions. ((juxt :a :b) {:a 1 :b 2 :c 3 :d 4}) ;;=> [1 2]

by kotarak on 2010-07-15 . May have evaluation errors. ▶

;; "Explode" a value. ((juxt identity name) :keyword) ;;=> [:keyword "keyword"] (juxt identity name) ...is the same as: (fn [x] [(identity x) (name x)]) ;; eg. to create a map: (into {} (map (juxt identity name) [:a :b :c :d])) ;;=> {:a "a" :b "b" :c "c" :d "d"}

by adie on 2010-07-27 ▶

;; Get the first character and length of string ((juxt first count) "Clojure Rocks") ;;=> [\C 13]

by ordnungswidrig on 2012-07-17 ▶

;; sort list of maps by multiple values (sort-by (juxt :a :b) [{:a 1 :b 3} {:a 1 :b 2} {:a 2 :b 1}]) ;;=> [{:a 1 :b 2} {:a 1 :b 3} {:a 2 :b 1}]

by Phalphalak on 2014-02-15 ▶

;; Create lookup maps via a specific key (defn index-by [coll key-fn] (into {} (map (juxt key-fn identity) coll))) ;; #'user/index-by (index-by [{:id 1 :name "foo"} {:id 2 :name "bar"} {:id 3 :name "baz"}] :id) ;;=> {1 {:name "foo", :id 1}, ;; 2 {:name "bar", :id 2}, ;; 3 {:name "baz", :id 3}} (index-by [{:id 1 :name "foo"} {:id 2 :name "bar"} {:id 3 :name "baz"}] :name) ;;=> {"foo" {:name "foo", :id 1}, ;; "bar" {:name "bar", :id 2}, ;; "baz" {:name "baz", :id 3}}

by d9k on 2015-04-06 ▶

((juxt + * min max) 3 4 6) ;;=> [13 72 3 6]

by frolovv on 2015-09-29 ▶

;; split a sequence into two parts ((juxt take drop) 3 [1 2 3 4 5 6]) ;; => [(1 2 3) (4 5 6)]

by clojurianix on 2016-05-19 ▶

;; Segregate even and odd numbers in collection. ((juxt (partial filter even?) (partial filter odd?)) (range 0 9)) ;;=> [(0 2 4 6 8) (1 3 5 7)]

by sleyzerzon on 2016-06-07 . May have evaluation errors. ▶

;;keywords serve as getter functions to produce an ordered vector ((juxt :lname :fname) {:fname "Bill" :lname "Gates"}) => ["Gates" "Bill"]

by lmccombes on 2016-10-22 . May have evaluation errors. ▶

;; sort by two values (sort-by (juxt :a :b) [{:a 2 :b 4} {:a 1 :b 2} {:a 2 :b 1}]) => ({:a 1, :b 2} {:a 2, :b 1} {:a 2, :b 4})

by smnplk on 2018-10-13 . May have evaluation errors. ▶

;; something similar to group-by (def split-by (juxt filter remove)) (split-by pos? [-1 -2 4 5 3 -9]) => [(4 5 3) (-1 -2 -9)]

by AbhishekJaiswal123 on 2022-05-11 . May have evaluation errors. ▶

;; Extract nested value from the map ((juxt :a #(get-in % [:c :d])) {:a 1 :b 2 :c {:d 2}}) => [1 2]

Note by Nevena

I kinda love this fn =)

Note by lispro06

"reduce1" -> "reduce"

core sources from 33 line to 37 line

See also

• clojure.core/partial (10)
• clojure.core/comp (15)
• clojure.core/every-pred (2)

---

Content from the matching ClojureDocs page, with authors credited on each contribution.