`clojure.core/format`¶

Type: function Added: Clojure 1.0 Examples: 6 Runnable: 2

([fmt & args])

Formats a string using java.lang.String.format, see java.util.Formatter for format string syntax

Examples¶

by Jacolyte on 2010-07-23

by jafingerhut on 2012-03-11 . May have evaluation errors.

(format "%5d" 3)
"    3"

(format "Pad with leading zeros %07d" 5432)
"Pad with leading zeros 0005432"

(format "Left justified :%-7d:" 5432)
"Left justified :5432   :"

(format "Locale-specific group separators %,12d" 1234567)
"Locale-specific group separators    1,234,567"

(format "decimal %d  octal %o  hex %x  upper-case hex %X" 63 63 63 63)
"decimal 63  octal 77  hex 3f  upper-case hex 3F"

(format "%2$d %1$s" "Positional arguments" 23)
"23 Positional arguments"

;;    ====== Clojure format/printf and large integers =====

;; This big number doesn't fit in a Long.  It is a
;; clojure.lang.BigInt, which format cannot handle directly.
(format "%5d" 12345678901234567890)
IllegalFormatConversionException d != clojure.lang.BigInt  java.util.Formatter$FormatSpecifier.failConversion (Formatter.java:3999)

;; You can convert it to a java.math.BigInteger, which format does handle.
(format "%5d" (biginteger 12345678901234567890))
"12345678901234567890"

;; If you do this very often, you might want to use something like
;; format-plus to avoid sprinkling your code with calls to biginteger.
(defn coerce-unformattable-types [args]
  (map (fn [x]
         (cond (instance? clojure.lang.BigInt x) (biginteger x)
               (instance? clojure.lang.Ratio x) (double x)
               :else x))
       args))

(defn format-plus [fmt & args]
  (apply format fmt (coerce-unformattable-types args)))

;; Now this works:
(format-plus "%5d" 12345678901234567890)
"12345678901234567890"

by jafingerhut on 2012-03-11 . May have evaluation errors.

;;  ==== Clojure format/printf and floating-point formats ====
(format "%.3f" 2.0)
"2.000"

;; format doesn't handle integers or ratios with %e, %f, %g, or %a
(format "%.3f" 2)
IllegalFormatConversionException f != java.lang.Long  java.util.Formatter$FormatSpecifier.failConversion (Formatter.java:3999)

;; In general, if you want to use floating-point formats %e, %f, %g,
;; or %a with format or printf, and you don't know whether the values
;; you want to format are floats or doubles, you should convert them:
(format "%.3f" (double 2))
"2.000"

(format "%.3f" (double (/ 5 2)))
"2.500"

;; One could make a function that parses the format string to look for
;; %f and other floating-point formats and automatically coerces the
;; corresponding arguments to doubles, but such a function probably
;; wouldn't fit into a short example.  You could also consider using
;; cl-format which does handle these kinds of things for you.  The main
;; disadvantage to doing so is that you have to learn a different syntax
;; for format specifiers.

by mars0i on 2015-07-26 . May have evaluation errors.

by andreasguther on 2022-03-13

by Kynde on 2022-09-14 . May have evaluation errors.

Note by timgilbert¶

Note that (format) is not currently supported in ClojureScript, only in Clojure.

Note by PEZ¶

For ClojureScript there is https://github.com/quoll/clormat. As of this writing it is new and because of that maybe not always fully compliant. Afaiu the goal is to make it fully compliant.

Note by grav¶

There's also Google Closure's format for ClojureScript. Example usage.

clojure.core/format¶

Examples¶

Note by timgilbert¶

Note by PEZ¶

Note by grav¶

See also¶

`clojure.core/format`¶