`clojure.core/await`¶

Type: function Added: Clojure 1.0 Examples: 2 Runnable: 0

([& agents])

Blocks the current thread (indefinitely!) until all actions dispatched thus far, from this thread or agent, to the agent(s) have occurred. Will block on failed agents. Will never return if a failed agent is restarted with :clear-actions true or shutdown-agents was called.

Examples¶

by ghoseb on 2010-09-05 . May have evaluation errors.

by phreed on 2015-06-23 . May have evaluation errors.

(import '(java.io BufferedWriter FileWriter))

;; Generally the agent can be sent messages asynchronously, send and forget.
;; In some cases a rendezvous is needed, e.g. in the case of an output file.

(def write-out 
  (agent {:handle (clojure.java.io/writer "results.txt" )
          :last-msg ["init"]}
        :validator (fn [state] 
                       (and (contains? state :handle) (contains? state :last-msg))) 
        :error-handler (fn [result] 
                           (println "invalid result") )))

(defn write-a-line [state msg nap] 
  (.write (:handle state) (str msg " line " "\n")) 
  (let [new-state (update-in state [:last-msg] into [msg])]
    (println "message : " msg " : " new-state)
    (Thread/sleep nap)
    new-state))

;; these all have the same return value
(send-off write-out write-a-line "first" 2000)
(send-off write-out write-a-line "second" 1000)
(send-off write-out write-a-line "third" 5000)
(send-off write-out write-a-line "fourth" 1000)
@write-out
;;=> {:handle #<BufferedWriter java.io.BufferedWriter@e175cca>, :last-msg ["init"]}

(time (await write-out))
;; 9000.307 msecs

;; here we can see that the await causes the thread to block
;; until the agent's queue is empty.
@write-out
;;=> {:handle #<BufferedWriter java.io.BufferedWriter@e175cca>, 
;;    :last-msg ["init" "first" "second" "third" "fourth"]}

;; But wait the "result.txt" file is empty!
;; We need to close the file handle.
;; And now that we know the agent's queue is empty we
;; are free to close it.
;; This could do this in the current thread with the dereferenced
;; agents :handle '(.close (:handle @write-out))' 
;; but it is probably better to be formal and let the agent do it.
(defn close-the-agent [state] 
  (.close (:handle state)) 
  state)

(send-off write-out close-the-agent)

;; And the contents of "result.txt" are: (less the leading '; ')
; first line
; second line
; third line
; fourth line

Note by andrewni420¶

;;It is not actually allowed to await on an action dispatched from an agent to an agent

(def m (agent 0))
(def n (agent 0))

(defn step 
  [agent1 agent2]
  (try (await (send agent2 inc))
       (catch Exception e (println e)))
  agent1)

;;Evaluating this throws an error saying "Can't await in agent action"
(send m #(step % n))

clojure.core/await¶

Examples¶

Note by andrewni420¶

See also¶

`clojure.core/await`¶