clojure.core/assoc-in

View this page on ClojureDocs

Type: function Added: Clojure 1.0 Examples: 9 Runnable: 7

([m [k & ks] v])

Associates a value in a nested associative structure, where ks is a sequence of keys and v is the new value and returns a new nested structure. If any levels do not exist, hash-maps will be created.

Examples

by zk on 2010-07-12 ▶

(def users [{:name "James" :age 26} {:name "John" :age 43}]) ;; update the age of the second (index 1) user (assoc-in users [1 :age] 44) ;;=> [{:name "James", :age 26} {:name "John", :age 44}] ;; insert the password of the second (index 1) user (assoc-in users [1 :password] "nhoJ") ;;=> [{:name "James", :age 26} {:password "nhoJ", :name "John", :age 43}] ;; create a third (index 2) user ;; Also (assoc m 2 {...}) or (conj m {...}) (assoc-in users [2] {:name "Jack" :age 19}) ;;=> [{:name "James", :age 26} {:name "John", :age 43} {:name "Jack", :age 19}] ;; From http://clojure-examples.appspot.com/clojure.core/assoc-in

by devth on 2013-09-11 ▶

;; can be used to update a mutable item. (def ppl (atom {"persons" {"joe" {:age 1}}})) (swap! ppl assoc-in ["persons" "bob"] {:age 2}) @ppl ;;=> {"persons" {"joe" {:age 1}, "bob" {:age 2}}}

by pmbauer on 2014-09-29 ▶

;; be careful with that empty path sequence, it's seldom what you want (assoc-in {} [] {:k :v}) ;;=> {nil {:k :v}} ;; In general, you find that for a non-empty path ;; (get-in (assoc-in m path v) path) ;; is equal to v. ;; Surprisingly this does not hold true in case of an empty path.

by saiberz on 2014-12-12 ▶

;; another example of updating a mutable item. ;; this time the first key is to a map and the second to a vector. (def foo (atom {:users [{:a "a"} {:b "b"}]})) (swap! foo assoc-in [:users 2] {:c "c"}) ;;=> {:users [{:a "a"} {:b "b"} {:c "c"}]}

by cthulhu-bot on 2015-06-10 ▶

;; assoc-in into a nested map structure (def foo {:user {:bar "baz"}}) (assoc-in foo [:user :id] "some-id") ;;=> {:user {:bar "baz", :id "some-id"}}

by prudentbot on 2015-07-28 ▶

(assoc-in {} [:cookie :monster :vocals] "Finntroll") ; => {:cookie {:monster {:vocals "Finntroll"}}} (get-in {:cookie {:monster {:vocals "Finntroll"}}} [:cookie :monster]) ; => {:vocals "Finntroll"} (assoc-in {} [1 :connections 4] 2) ; => {1 {:connections {4 2}}} ;; from http://www.braveclojure.com/functional-programming/

by amirrajan on 2015-10-23 ▶

;; assoc-in can be used on vectors too (def row 0) (def col 0) (assoc-in [[1 1 1] [1 1 1] [1 1 1]] [row col] 0) ; => [[0 1 1][1 1 1][1 1 1]] (get-in [[0 1 1] [1 1 1] [1 1 1]] [row col]) ; => 0

by gosukiwi on 2016-08-07 . May have evaluation errors. ▶

; Playing around with assoc-in (assoc-in {:person {:name "Mike"}} [:person :name] "Violet") ; => {:person {:name "Violet"}} (assoc-in {:person {:name "Mike"}} [:person] "Violet") ; => {:person "Violet"} (assoc-in [{:person {:name "Mike"}}] [0 :person :name] "Violet") ; => [{:person {:name "Violet"}}] (assoc-in [{:person {:name ["Mike"]}}] [0 :person :name 1] "Smith") ; => [{:person {:name ["Mike" "Smith"]}}] (assoc-in [{:person {:name ["Mike"]}}] [0 :person :name 2] "Smith") ; => IndexOutOfBoundsException

by bfontaine on 2018-04-18 . May have evaluation errors. ▶

;; Note that, unlike `assoc`, `assoc-in` cannot be used with multiple values. (def my-map {}) ;; This works (assoc my-map :a 1 :b 2 :c 3) ; => {:a 1, :b 2, :c 3} ;; This doesn’t (assoc-in my-map [:a :aa] 1 [:b :bb] 2 [:c :cc] 3) ; ArityException Wrong number of args (7) passed to: core/assoc-in ;; This works (-> my-map (assoc-in [:a :aa] 1) (assoc-in [:b :bb] 2) (assoc-in [:c :cc] 3))

Note by Crowbrammer

Unlike assoc, you can only do one kv at a time:

;; Allowed
(assoc {} :a "a" :b "b" :c "c")
;; Not allowed:
(assoc-in {} [:a :b] "cya" [:a :d :e] "f" [:b :g] "wow")

See also

• clojure.core/assoc (8)
• clojure.core/update-in (10)
• clojure.core/get-in (5)
• clojure.core/associative?

---

Content from the matching ClojureDocs page, with authors credited on each contribution.