clojure.core/->>

View this page on ClojureDocs

Type: macro Added: Clojure 1.1 Examples: 11 Runnable: 7

([x & forms])

Threads the expr through the forms. Inserts x as the last item in the first form, making a list of it if it is not a list already. If there are more forms, inserts the first form as the last item in second form, etc.

Examples

by tomoj on 2010-07-24 ▶

;; An example of using the "thread-last" macro to get ;; the sum of the first 10 even squares. (->> (range) (map #(* % %)) (filter even?) (take 10) (reduce +)) 1140 ;; This expands to: (reduce + (take 10 (filter even? (map #(* % %) (range))))) 1140

by BertrandDechoux on 2012-06-09 ▶

(def c 5) (->> c (+ 3) (/ 2) (- 1)) 3/4 ;; and if you are curious why (use 'clojure.walk) (macroexpand-all '(->> c (+ 3) (/ 2) (- 1))) (- 1 (/ 2 (+ 3 c)))

by deddu on 2015-04-29 ▶

;; let's compare thread first (->) and thread last ( ->> ) (macroexpand '(-> 0 (+ 1) (+ 2) (+ 3))) (+ (+ (+ 0 1) 2) 3) (macroexpand '(->> 0 (+ 1) (+ 2) (+ 3))) (+ 3 (+ 2 (+ 1 0)))

by rsachdeva on 2015-11-17 . May have evaluation errors. ▶

;; ->> and -> by simple string concatenation ;; Effectively (str " jmd" "hello") (->> "hello" (str " jmd")) " jmdhello" ;; Effectively (str "hello" " jmd") (-> "hello" (str " jmd")) => "hello jmd"

by huahaiy on 2016-05-27 . May have evaluation errors. ▶

;; It is OK to omit the parentheses if a function takes only one argument (->> [1 2 [3 4] 5] flatten ; no parenthesis (map inc)) => (2 3 4 5 6)

by huahaiy on 2016-05-27 . May have evaluation errors. ▶

;; It's OK to include anonymous function in the thread, but don't forget ;; to put in an extra pair of parentheses to call the function (->> [1 2 3 4 5] ((fn [coll] (map inc coll))) ; double parentheses (apply +)) => 20 ;; the short hand form of the anonymous function works the same (->> [1 2 3 4 5] (#(map inc %)) ; double parentheses (apply +)) ;; avoid function (->> [1 2 3 4 5] (map inc) ; single parentheses (apply +))

by rafmagana on 2016-06-01 . May have evaluation errors. ▶

;; For large threads you can use commas (interpreted as whitespaces) ;; to visualize where the items are going to be inserted. ;; Takes the first 5 even numbers (->> (range) (filter even?) (take 5)) => (0 2 4 6 8) ;; with two commas (you can use one if you prefer) (->> (range) (filter even? ,,) (take 5 ,,)) => (0 2 4 6 8) ;; For instance: ;; (filter even? ,,) ;; means ;; (filter even? (range))

by ibercode on 2018-01-27 ▶

;;practical example (def entries [{:month 1 :val 12} {:month 2 :val 3} {:month 3 :val 32} {:month 4 :val 18} {:month 5 :val 32} {:month 6 :val 62} {:month 7 :val 12} {:month 8 :val 142} {:month 9 :val 52} {:month 10 :val 18} {:month 11 :val 23} {:month 12 :val 56}]) (defn get-result [coll m] (->> coll (take-while #(<= (:month %) m)))) (defn get-total [coll m] (->> (get-result coll m) (map #(:val %)) (reduce +))) (get-total entries 3)

by ibercode on 2018-02-17 ▶

(defn new-map [coll] (->> coll (map (fn [[k v]] [k (inc v)])) (into {}))) (new-map {:a 1 :b 2 :c 3})

by ningDr on 2019-06-29 ▶

(defn f [front a1 a2 end] (str front "-" a1 "-" a2 "-" end)) (println (f 1 2 3 4)) ;; => 1-2-3-4 (println (-> 1 (f 2 3 4))) ;; => 1-2-3-4 (println (->> 1 (f 2 3 4))) ;; => 2-3-4-1

by harelix on 2021-09-01 ▶

(->> (str "A") (str "B") (str "C")) ;; => "CBA" (-> (str "A") (str "B") (str "C")) ;; => "ABC"

Note by Jacolyte

I'm getting: Exception in thread "main" java.lang.Exception: Unable to resolve symbol: ->> in this context (11.clj:25)

It's also extremely hard to Google this method. It'd be nice if there was a non-symbol name for this that one could search for.

Update

The name of this operator is called a thrush.

Note by steveminer

See also -> which is similar but threads the first expr as the second argument of the forms.

Note by Jacolyte

My error was due to using an old version of Clojure. I was using 1.0.0.

Note by nmichel

There is something I don't get : in the case "form" is a seq, why should we write ... (with-meta `(~(first form) ~@(next form) ~x) (meta form))

and not ... (with-meta `(~@form ~x) (meta form))

as items order in "form" is not changed ?

Note by nzl-nott

"See also -> which is similar but threads the first expr as the second argument of the forms."

This is incorrect, it is not the second ARGUMENT, but the second ITEM.

See also

• clojure.core/-> (4)
• clojure.core/some->>
• clojure.core/comp (15)
• clojure.core/cond->>
• clojure.core/cond-> (4)
• clojure.core/as-> (4)

---

Content from the matching ClojureDocs page, with authors credited on each contribution.